// ---< classe cellule
load_file("nrngui.hoc")

dt=0.1

begintemplate my_cell
	public soma, axon, dend, dend_syn, dend_syn1, soma_syn, plug_it, plug_it1
	create soma,axon,dend
	objref dend_syn
	objref dend_syn1
	objref soma_syn
	objref netcon
	objref netcon1
	proc init() {
		soma {				
			nseg = 1
			diam = 18.8
			L = 18.8
			Ra = 123.0
			insert hh
			gnabar_hh=0.12
			gkbar_hh=0.036
			gl_hh = .0001666
			el_hh = -60.0
		}
	
		dend {
			nseg = 10
			diam = 3.18
			L = 701.9
			Ra = 123
			insert pas
			g_pas = .0001666
			e_pas = -60.0
			dend_syn=new ExpSyn(1)
			dend_syn1=new ExpSyn(1)
		}
	
		axon {
			nseg = 100
			diam = 2.0
			L = 549.1
			Ra = 123
			insert hh
			gnabar_hh=0.12
			gkbar_hh=0.036
			gl_hh = .0001666
			el_hh = -60.0
		}
	
		//---< Connect things together
		connect dend(0), soma(0)
		connect axon(0), soma(1)
	}
	// ---< ajouter la cellule de destination
	proc plug_it(){
		axon netcon=new NetCon(&v(0.995),$o1.dend_syn,-40,0,0.025)
	}
	proc plug_it1(){
		axon netcon1=new NetCon(&v(0.995),$o1.dend_syn1,-40,0,0.025)
	}
endtemplate my_cell

// ---< preparation du reseau
nmy_cells = 3
objectvar my_cells[nmy_cells]
for i = 0, nmy_cells-1 {
	my_cells[i] = new my_cell()
}
my_cells[0].plug_it(my_cells[2])
my_cells[1].plug_it(my_cells[0])
my_cells[2].plug_it(my_cells[1])
my_cells[2].plug_it1(my_cells[0])

// ---< construction des stimulateurs
objref stim[3]
my_cells[0].soma {
    stim[0] = new IClamp(0.5)
}
my_cells[1].soma {
    stim[1] = new IClamp(0.5)
}
my_cells[2].soma {
    stim[2] = new IClamp(0.5)
}
objref g1,g2,g3


proc update(){
	tstop=fin
	t=0
	
	my_cells[0].dend_syn.e=e_d_0
	my_cells[0].dend_syn.tau=tau_d_0
	my_cells[1].dend_syn.e=e_d_1
	my_cells[1].dend_syn.tau=tau_d_1
	my_cells[2].dend_syn.e=e_d_2
	my_cells[2].dend_syn.tau=tau_d_2
	my_cells[0].dend_syn1.e=e_d_2
	my_cells[0].dend_syn1.tau=tau_d_2
	
	NetCon[0].weight=w_0
	NetCon[1].weight=w_1*10
	NetCon[2].weight=w_2
	NetCon[3].weight=w_0

	NetCon[0].delay=del_0
	NetCon[1].delay=del_1
	NetCon[2].delay=del_2
	NetCon[3].delay=del_0

    stim[0].del = ddel_0
    stim[0].dur = ddur_0
    stim[0].amp = amp_0

    stim[1].del = ddel_1
    stim[1].dur = ddur_1
    stim[1].amp = amp_1

    stim[2].del = ddel_2
    stim[2].dur = ddur_2
    stim[2].amp = amp_2

    g1.size(0,tstop,-80,40)
    g2.size(0,tstop,-80,40)
    g3.size(0,tstop,-80,40)
    
    aa=0.12
    bb=0.036
    if (ttx==1) aa=0
    if (tea==1) bb=0
    for (i=0;i<nmy_cells;i=i+1){
    	my_cells[i].soma.gnabar_hh=aa
    	my_cells[i].axon.gnabar_hh=aa
    	my_cells[i].soma.gkbar_hh=bb
    	my_cells[i].axon.gkbar_hh=bb
    }
    NetCon[1].weight=NetCon[1].weight*(1-picro)
    NetCon[0].weight=NetCon[0].weight*(1-CNQX)
    NetCon[2].weight=NetCon[2].weight*(1-CNQX)
    NetCon[3].weight=NetCon[3].weight*(1-CNQX)
	NetCon[2].weight=NetCon[2].weight*(1-Cd)
    NetCon[0].weight=NetCon[0].weight*(1-Cd)
    NetCon[1].weight=NetCon[1].weight*(1-Cd)
    NetCon[3].weight=NetCon[3].weight*(1-Cd)
}

proc init_it(){
	w_0=5
	w_1=5
	w_2=5
	del_0=4
	del_1=2
	del_2=12
	tau_d_0=1.5
	tau_d_1=0.25
	tau_d_2=0.25
	e_d_0=-80
	e_d_1=0
	e_d_2=0
	fin=100
	ddel_0=0
	ddur_0=0
	amp_0=0
	ddel_1=0
	ddur_1=0
	amp_1=0
	ddel_2=0
	ddur_2=0
	amp_2=0
	ttx=0
	tea=0
	picro=0
	CNQX=0
	Cd=0

	update()
}

objref main
main=new HBox(2)
main.intercept(1)

xpanel("electrodes")
xlabel("simulation")
xvalue("Duree de simulations","int(fin)")
xslider(&fin,1,100,"update()",0)
xlabel("Reseau")

xlabel("Stimulateur 0 (cellule 0)")
xvalue("Amp ","amp_0")
xslider(&amp_0,0,1,"update()",0)
xvalue("Delai ","ddel_0")
xslider(&ddel_0,0,100,"update()",0)
xvalue("Duree ","ddur_0")
xslider(&ddur_0,0,100,"update()",0)

xlabel("Stimulateur 1 (cellule 1)")
xvalue("Amp ","amp_1")
xslider(&amp_1,0,1,"update()",0)
xvalue("Delai ","ddel_1")
xslider(&ddel_1,0,100,"update()",0)
xvalue("Duree ","ddur_1")
xslider(&ddur_1,0,100,"update()",0)

xlabel("Stimulateur 2 (cellule 2)")
xvalue("Amp ","amp_2")
xslider(&amp_2,0,1,"update()",0)
xvalue("Delai ","ddel_2")
xslider(&ddel_2,0,100,"update()",0)
xvalue("Duree ","ddur_2")
xslider(&ddur_2,0,100,"update()",0)

xpanel()

xpanel("Reseau")
xlabel("Drogues")
xcheckbox("TTX",&ttx,"update()")
xcheckbox("Picrotoxine",&picro,"update()")
xcheckbox("CNQX",&CNQX,"update()")
xcheckbox("Cd2+",&Cd,"update()")
xlabel("Enregistrement")
xbutton("GO","run_it()")
xlabel("Init")
xbutton("INIT","init_it()")
xpanel()

objref main1
main1=new VBox(2)
main1.intercept(1)

g1=new Graph()
g1.size(0,tstop,-80,40)
g1.addexpr("my_cells[0].soma.v(0.5)",2,2)
g1.addexpr("my_cells[0].axon.v(0.5)",4,2)
g1.addexpr("my_cells[0].dend.v(0.5)",3,2)
g2=new Graph()
g2.size(0,100,-80,40)
g2.addexpr("my_cells[1].soma.v(0.5)",2,2)
g2.addexpr("my_cells[1].axon.v(0.5)",4,2)
g2.addexpr("my_cells[1].dend.v(0.5)",3,2)
g3=new Graph()
g3.addexpr("my_cells[2].soma.v(0.5)",2,2)
g3.addexpr("my_cells[2].axon.v(0.5)",4,2)
g3.addexpr("my_cells[2].dend.v(0.5)",3,2)

main1.intercept(0)
main1.map("Graphes",20,20,600,700)

main.intercept(0)
main.map("Global",20,20,1000,740)

init_it()

proc run_it(){
	update()
	g1.size(0,tstop,-80,40)
	g2.size(0,tstop,-80,40)
	g3.size(0,tstop,-80,40)
	g1.erase()
	g2.erase()
	g3.erase()
	g1.begin()
	g2.begin()
	g3.begin()
	finitialize(-64.43)
	while(t<tstop){
		fadvance()
		g1.plot(t)
		g2.plot(t)
		g3.plot(t)
	}
	g1.flush()
	g2.flush()
	g3.flush()
}